Gradle создает нулевой консольный объект

По какой-то причине запуск gradle в режиме демона приводит к нулевому объекту консоли. Если вы укажете соответствующий флаг командной строки,

./gradlew assembleRelease --no-daemon

это сработает.

Я нашел решение здесь по адресу https://www.timroes.de/2014/01/19/using-password-prompts-with-gradle-build-files и немного изменил его. Тем не менее, все заслуги Тима Роуза!

gradle.taskGraph.whenReady { taskGraph ->
if(taskGraph.hasTask(':app:assembleRelease')) {
    def storePass = ''
    def keyPass = ''
    if(System.console() == null) {
        new SwingBuilder().edt {
            dialog(modal: true, title: 'Enter password', alwaysOnTop: true, resizable: false, locationRelativeTo: null, pack: true, show: true) {
                vbox { // Put everything below each other
                    label(text: "Please enter store passphrase:")
                    def input1 = passwordField()
                    label(text: "Please enter key passphrase:")
                    def input2 = passwordField()
                    button(defaultButton: true, text: 'OK', actionPerformed: {
                        storePass = input1.password;
                        keyPass = input2.password;
                        dispose();
                    })
                }
            }
        }
    } else {
        storePass = System.console().readPassword("\nPlease enter store passphrase: ")
        keyPass = System.console().readPassword("\nPlease enter key passphrase: ")
    }

    if(storePass.size() <= 0 || keyPass.size() <= 0) {
        throw new InvalidUserDataException("You must enter the passwords to proceed.")
    }

    storePass = new String(storePass)
    keyPass = new String(keyPass)

    android.signingConfigs.release.storePassword = storePass
    android.signingConfigs.release.keyPassword = keyPass
    }
}

Где-то в каком-то файле gradle у вас есть конфигурация для подписания выпуска.

android {
...
signingConfigs {
    ...
    release {
        storeFile file(System.getProperty("user.home")+"\\android-key")
        storePassword ''
        keyAlias "standard"
        keyPassword ''
    }
}

...
}

(Не забудьте import groovy.swing.SwingBuilder.)

Что касается второй части, вы также можете взглянуть на Как создать apk-файл с подписью выпуска с помощью Gradle?

Хорошо, причина, по которой это не сработало, была глупой, но на случай, если кто-то еще столкнется с этим, я решил опубликовать.

Я выполнял задачу через студию Android и не понимал, что объект консоли всегда будет нулевым. При запуске из командной строки объект «команда» не равен нулю, и он работает нормально.

Выполнение System.getConsole() из Gradle, когда свойство org.gradle.daemon равно true, или когда оно выполняется из IDE, такой как IntelliJ или Android Studio, возвращается null. Так например сделать System.console().readLine() становится невозможным.

Кроме того, начиная с Gradle 3.0 gradle.daemon включен по умолчанию.

Затем вместо обходного пути для использования System.getConsole() я использую альтернативу, используя ant.input следующим образом:

task avoidNullOnConsole << {
    ant.input(message: 'Enter keystore password:', addproperty: 'userInputPassword', defaultValue : '1234')
    def password = ant.properties.userInputPassword
}

В этом случае ant.input показывает message и добавляет пользовательский ввод в ant.properties, используя в качестве имени свойства значение, определенное в addProperty. Если пользовательский ввод отсутствует, используется значение, определенное в атрибуте default.

После выполнения вы можете получить пользовательский ввод, используя ant.properties.yourProperty или ant.properties['yourProperty'].

Вы можете проверить остальные атрибуты ant.input здесь.

Примечание. Если вы хотите использовать ant.input несколько раз, учтите, что вы не можете переопределить существующее свойство, поэтому атрибут addProperty должен быть разным для каждого из них.

Взгляните на этот пост в блоге (https://www.timroes.de/2013/09/22/handling-signing-configs-with-gradle/).

В нем описывается несколько способов обработки конфигураций подписи, и один из них — это как раз ваш вопрос о консольном вводе пароля.

Чтобы обойти эту проблему, я использовал стандартный поток ввода следующим образом:

println "Enter keystore password"
def password = System.in.newReader().readLine()

Вы также можете выполнить свой скрипт с помощью:

-Dorg.gradle.daemon=false

Простое решение — проверить объект консоли на значение null:

def password = null
def console = System.console()
if (console != null) {
    password = console.readLine("Enter keystore password: ")
}

Android Studio больше не жалуется на файл null object.

Чтобы скрыть введенные символы, используйте readPassword() вместо readLine():

password = new String(console.readPassword("\nEnter key password: "))

создайте простую функцию для запроса пароля:

import javax.swing.JOptionPane

def askPass() {
  def msg = 'Enter keystore password'
  if (System.console() != null) {
    return System.console().readLine(msg)
  } else {
    return javax.swing.JOptionPane.showInputDialog(msg)
  }
}

или если вы хотите ответ Y/n:

import javax.swing.JOptionPane

def ask(msg) {
  if (System.console() != null) {
    return System.console().readLine(msg + ' [y/n]') == 'y'
  } else {
    def res = JOptionPane.showConfirmDialog(null, msg, "Confirm operation", JOptionPane.YES_NO_OPTION)
    return res == JOptionPane.YES_OPTION
  }
}

// usage:

task run() {
  doFirst {
    if (file('out.txt').exists() && !ask('overwrite output?')) {
      System.exit(2)
    }
  }
  ...
}