Удаление или отключение элемента ComboBox, который выбран в другом списке

Это похоже на ответ Стива, но использует DataSource. Кроме того, нет реальной необходимости Enable/Disable каждого CBO. По мере внесения изменений предыдущие выборки отфильтровываются из источника. Любые повторяющиеся «предыдущие» изменения отменяются.

CBO1 всегда имеет полный список, в то время как другие пропускают предыдущие выборы. Вы не можете получить дубликаты выбора, потому что повторный выбор № 2 таким же, как № 3, изменяет содержимое № 3, заменяя выбор тем, что находится первым в списке.

' the master list
Private OptList As New List(Of String)
Private ignore As Boolean

' initialize somewhere:
OptList.AddRange(New String() {"Red", "Green", "Blue", "Violet", "Orange"})
' set up cbos
' ignore changes while setting up:
ignore = True
cb1.DataSource = OptList.ToArray
cb1.SelectedIndex = -1
cb2.DataSource = OptList.ToArray
cb2.SelectedIndex = -1
cb3.DataSource = OptList.ToArray
cb3.SelectedIndex = -1
ignore = False

Когда они все включены, они могут выбирать их в любом порядке.

Private Sub cbo_SelectedIndexChanged(sender As Object, e As EventArgs) _
             Handles cb1.SelectedIndexChanged, cb2.SelectedIndexChanged
    If ignore Then Exit Sub

    Dim cbo = TryCast(sender, ComboBox)
    If cbo IsNot Nothing AndAlso cbo Is cb1 Then
        cb2.DataSource = GetFilteredList(New String() {cb1.Items(cb1.SelectedIndex)})
    Else
        cb3.DataSource = GetFilteredList(New String() {cb1.SelectedItem.ToString,
                                                   cb2.SelectedItem.ToString})
    End If
End Sub

Private Function GetFilteredList(items As String()) As String()
    Return OptList.Except(items).ToArray()
End Function

Поскольку cbo3 ограничен теми предметами, которые не выбраны в #1 или #2 (раб), вам не нужно ничего делать, когда этот выбор изменится.

Could this be expanded to say 9 cbo by continuing multiple if/else statements и How would I keep the first option. Say if I wanted to include a "None" option always available.

Что то много, я бы сделал это более абстрактно. Код может быть сложнее читать/следовать, но его меньше (я использовал 4 cbos). Это может потребовать некоторой настройки, так как это не в моей голове для последующей исправленной формы:

' additional array to hold the CBOs involved
Private tgtCBOs As ComboBox()
...
' initialization:
OptList.AddRange(New String() {"(None)", "Red", "Green", "Blue", "Violet", 
                       "Orange", "Mauve", "White"})
tgtCBOs = New ComboBox() {cb1, cb2, cb3, cb4}

' set initial index to 0 with a default item

Private Sub cb2_SelectedIndexChanged(sender As Object, e As EventArgs) Handles _ 
        cb2.SelectedIndexChanged, cb1.SelectedIndexChanged, cb3.SelectedIndexChanged

    If ignore Then Exit Sub

    Dim cbo = TryCast(sender, ComboBox)
    ' identify which one this is
    Dim ndx = Array.IndexOf(tgtCBOs, cbo)
    ' get all the selections from 0 to here
    Dim exclude = GetExclusionList(ndx)
    ' remove excludes from the NEXT cbo
    Dim newList As New List(Of String)
    If ndx + 1 < tgtCBOs.Length Then
        newList = OptList.Except(exclude).ToList()
        If newList(0) <> OptList(0) Then newList.Insert(0, "(None)")
        tgtCBOs(ndx + 1).DataSource = newList.ToArray()
    End If
End Sub

Private Function GetExclusionList(ndx As Int32) As List(Of String)
    Dim exclude As New List(Of String)
    For n As Int32 = 0 To ndx
        If tgtCBOs(n).SelectedIndex <> -1 Then
            exclude.Add(tgtCBOs(n).Items(tgtCBOs(n).SelectedIndex).ToString())
        End If
    Next
    Return exclude
End Function

Обратите внимание, что последний cbo не подключен к этому обработчику, потому что у него нет «ведомого». Подключите его к собственному обработчику, если вам нужно отреагировать на событие.

Кроме того, действие сброса DataSource для «следующего» (или очистки элементов в этом отношении) вызовет срабатывание этого события для следующего/дочернего/ведомого CBO. Таким образом, изменение CBO2 вызовет событие для 3, 4, 5..n. Он также сбрасывает предыдущий выбор в дочерних/ведомых/следующих.

Итак, предположим, что ваши поля со списком называются b1, b2 и b3. Все эти комбинации связаны с одним и тем же обработчиком событий SelectedIndexChanged, и (как вы говорите) вы установили начальные элементы в b1, b2 и b3 в фиксированный список строк.

Теперь вы также должны установить для свойства Enabled b2 и b3 значение false и позволить выбору b1 управлять вашей логикой в ​​событии SelectedIndexChanged.

Sub onIndexChanged(sender As Object, e As EventArgs)
    Dim b As ComboBox = CType(sender, System.Windows.Forms.ComboBox)
    If b.Equals(b1) Then
        If b1.SelectedIndex = -1 Then

            b2.Enabled = False
            b3.Enabled = False
        Else
            b2.Enabled = True
            b3.Enabled = False
            b2.Items.Clear()
            b3.Items.Clear()
            b2.Items.AddRange(b1.Items.Cast(Of String)() _
             .Where(Function(x) x <> b1.SelectedItem.ToString()).ToArray())
        End If
    Else if b.Equals(b2) Then
        If b2.SelectedIndex <> -1 Then

            b3.Items.Clear()
            b3.Items.AddRange(b2.Items.Cast(Of String)(). _
                Where(Function(x) x <> b2.SelectedItem.ToString()).ToArray())
            b3.Enabled = True
            b3.SelectedIndex = 0
        End If 
    End If 
End Sub