Дублированный родительский элемент XSL для каждого вхождения дочернего элемента

<xsl:apply-templates select="Customer/Market">
    <xsl:sort select="MarketNumber" data-type="number" order="ascending"/>
</xsl:apply-templates>
...
<xsl:template match="Market">
    <!--Duplicate all customer data for each market-->
    <Customer>
        <xsl:copy-of select="../*[not(self::Market)] | ."/>
    </Customer>
</xsl:template>

Это скопирует все элементы того же уровня, которые не являются элементами Market, а также скопирует текущий (совпадающий) элемент Market. Это то, что вы хотели?

Я опоздал на вечеринку на несколько лет, но у меня было это требование. Решение, которое я придумал, состояло в том, чтобы использовать именованные шаблоны для рекурсивного копирования XML-дерева, исключая имена элементов, которые я не хотел копировать, и используя функцию generate-id для идентификации узла, который я все еще хотел скопировать. См. комментарии в приведенном ниже коде для более подробной информации.

Это решение работает в XSLT 1.0.

Пример XSLT Fiddle доступен здесь: https://xsltfiddle.liberty-development.net/bnnZWm.

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
  exclude-result-prefixes="msxsl"
>
  <xsl:output method="xml" indent="yes"/>

  <!-- copy everything as is, unless told otherwise-->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- 
  match on the document element
  ensure there's a single root element, Customers
  match on any Market nodes, so we get a copy of everything for that Market's customer (as per the Market template) with that Market
  OR match any customer that doesn't have any markets; so we don't exclude those from the results (did you want that; if not switch the apply-templates for the commented out version below)
  -->
  <xsl:template match="/">
    <Customers>
      <xsl:apply-templates select="//Market|//Customer[not(./Markets/Market)]" />
      <!-- <xsl:apply-templates select="//Market" /> -->
    </Customers>
  </xsl:template>

  <!-- 
  For the markets matched above, call our copyAllButMe template
  set the rootNode (the node to be copied) to the current Market's ancestor Customer element
  set the ignoreElementName to the current element's name (i.e. so when copying the customer, we don't copy any child Market elements
  set the includeNodeId to the current element's id (i.e. so when ignoring other Markets, we don't ignore the current element)
  -->
  <xsl:template match="Market">
    <xsl:call-template name="copyAllButMe">
      <xsl:with-param name="rootNode" select="../.." />
      <xsl:with-param name="ignoreElementName" select="local-name()" />
      <xsl:with-param name="includeNodeId" select="generate-id()" />
    </xsl:call-template>
  </xsl:template>

  <!--
  Test: 
    Is the current element's name a name we should be ignoring?  
    If it is, does this element's ID match the ID we want to include?
  If we're not ignoring this element name, or the id is the one to include then we proceed:
  Copy the element's name
  Copy any attrinbutes of thie element
  Loop through all child nodes of this element
  - If the child node is itself an element, call this template (i.e. recursion)
  - Otherwise (e.g. it' text node, comment node, etc), copy the node as-is
  -->
  <xsl:template name="copyAllButMe">
    <xsl:param name="rootNode" />
    <xsl:param name="ignoreElementName" />
    <xsl:param name="includeNodeId" />
    <xsl:if test="(local-name($rootNode) != $ignoreElementName) or (generate-id($rootNode) = $includeNodeId)">
      <xsl:element name="{local-name($rootNode)}" namespace="{namespace-uri($rootNode)}">
        <xsl:copy-of select="$rootNode/attribute::*" />
        <xsl:for-each select="$rootNode/child::node()">
          <xsl:choose>
            <xsl:when test="self::*">
              <xsl:call-template name="copyAllButMe">
                <xsl:with-param name="rootNode" select="self::node()" />
                <xsl:with-param name="ignoreElementName" select="$ignoreElementName" />
                <xsl:with-param name="includeNodeId" select="$includeNodeId" />
              </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="self::node()" />
            </xsl:otherwise>
          </xsl:choose>
        </xsl:for-each>
      </xsl:element>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>