Как сделать все элементы управления в форме Delphi недоступными для редактирования / изменения, но все же разрешить пользователю копировать содержимое

Я думаю, вы можете эмулировать всплывающее меню для своих компонентов (потому что стандартное всплывающее меню не работает для отключенных).

Но если у вас будет всплывающее меню для формы и FormMouseDown обработчика событий, вы можете проанализировать, где находится указатель мыши (под каким компонентом, я имею в виду), и вызвать всплывающее окно с Copy элементом меню.

Быстрый пример для списков:

unit Unit6;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.Menus, Vcl.StdCtrls, Vcl.ExtCtrls, Clipbrd;

type
  TForm6 = class(TForm)
    Panel1: TPanel;
    ListBox1: TListBox;
    ListBox2: TListBox;
    PopupMenu1: TPopupMenu;
    miCopy: TMenuItem;
    procedure miCopyClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
  private
    { Private declarations }
    selectedText: string;
  public
    { Public declarations }
  end;

var
  Form6: TForm6;

implementation

{$R *.dfm}

procedure TForm6.FormCreate(Sender: TObject);
begin
  ListBox1.ItemIndex := 1;
  ListBox2.ItemIndex := 1;
  Panel1.OnMouseDown := FormMouseDown;
end;

procedure TForm6.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
var
  i, parentX, parentY: integer;
  p: TPoint;
  lb: TListBox;
begin
  if Button <> mbRight then
    exit;

  selectedText := '';
  for i := 0 to ComponentCount - 1 do
    if Components[i] is TListBox then
    begin
      lb := TListBox(Components[i]);
      begin
        p := lb.ParentToClient(Point(X, Y));
        if lb.ClientRect.Contains(p) then
        begin
          parentX := 0;
          parentY := 0;
          if Assigned(lb.Parent) then
          begin
            parentX := lb.Parent.ClientOrigin.X;
            parentY := lb.Parent.ClientOrigin.Y;
          end;

          if lb.ItemIndex > -1 then
          begin
            selectedText := lb.Items[lb.ItemIndex];
            PopupMenu1.Popup(lb.Left + parentX + p.X, lb.Top + parentY + p.Y);
          end;
          break;
        end;
      end;
    end;
end;

procedure TForm6.miCopyClick(Sender: TObject);
begin
  if selectedText = '' then
    exit;

  Clipboard.AsText := selectedText;
end;

end.

Здесь ListBox1 размещается на компоненте TPanel. Обратите внимание, что вы должны назначить обработчик OnMouseDown формы всем вашим панелям или другим контейнерам. Кроме того, если у вас есть вложенные контейнеры, вам нужно использовать рекурсивный алгоритм для поиска parentX, parentY.

Вы можете использовать этот код, чтобы сделать поле со списком доступным только для чтения. Также вы можете использовать тот же подход к другим изменениям, если вы можете получить дескриптор окна редактирования.

procedure MakeComboboxReadOnly(const ACombobox: TCombobox);
var cbi: TComboBoxInfo;
begin
    cbi.cbSize := SizeOf(cbi);
    GetComboBoxInfo(ACombobox.Handle, cbi);
    SendMessage(cbi.hwndItem, EM_SETREADONLY, 1, 0);
end;

Просто чтобы добавить закрытие к моему собственному вопросу. В конце концов, я сделал это, просто поместив кнопки скорости рядом с элементами управления, содержащими текст, который я хотел скопировать, и использовал обычный

uses ClipBrd;
...
Clipboard.AsText := MyControl1.text;

для копирования данных.

Уловка, однако, заключалась не в том, чтобы разместить кнопки скорости как дочерние элементы панели, содержащей элемент управления (которая отключена, следовательно, также отключает все элементы управления внутри нее), а вместо этого просто поместите их в форму, а затем переместите их так, чтобы они были расположены перед панелью рядом с соответствующим элементом управления.

Таким образом, кнопки скорости выглядят так, как будто они являются частью панели, но все равно будут работать, когда панель и все ее элементы управления отключены.